//green curve variables
int x;
float y;
float [] yArray;
boolean outGrid;

//background curve variables
float y1;
float y2;
float freq;
float amp;
boolean backgroundCurve;
  

void setup(){
  
  size(1000,400);
  
  //green curve variables
  x=1;
  yArray = new float [width+1];
  yArray[0]=(height/2);
  outGrid=false;
  
  //background curve variables
  backgroundCurve=true;
  freq = 2;
  amp=-(height/8);
}

void draw(){
  background(0);
  
  //sizes
  int widthSquare = 10;
  
  stroke(122);
  
  //draw x lines
  int yGrid=0;
  for (int i=0; i<((height)/widthSquare)+1; i++){
    line (0,yGrid,width,yGrid);
    yGrid+=widthSquare;
  }
  
  //draw y lines
  int xGrid=0;
  for (int i=0; i<(width/widthSquare); i++){
    line (xGrid,0,xGrid,height);
    xGrid+=widthSquare;
  }
  
  //draw background wave
  if (backgroundCurve==true){
    stroke(112);
    for (int i=1; i<width; i++){
      y1=(height/2)+(((height/2)+amp)*-sin((freq*TWO_PI/width)*(i-1)));
      y2=(height/2)+(((height/2)+amp)*-sin((freq*TWO_PI/width)*i));
      line(i-1,y1,i,y2);
    }
  }
  
  //draw axies
  stroke(0,255,0);
  line (0,(height)/2,width,(height)/2);//x axis
  line (width/2,0,width/2,height);//y axis
  
  //append point to yArray
  if (outGrid==false){
    y=(height/2)+(((height/2)+amp)*-sin((freq*TWO_PI/width)*x));
    yArray[x]=y;
  }
  
  //draw curve
  stroke(0,255,0);
  for (int i=1; i<=x; i++){
    line(i-1,yArray[i-1],i,yArray[i]);
  }
  
  //draw point
  
  if (outGrid==false){
    noStroke();
    fill(255,0,0);
    ellipse(x,yArray[x],8,8);
  }
  
  //x handling
  if (x==width){
    outGrid=true;
  }
  else{
    x++;
  }
}

void keyPressed() {
  if (key==CODED){
    if (keyCode==UP){
      amp+=(height/40);
    }
    if (keyCode==DOWN){
      amp-=(height/40);
    }
    if (keyCode==LEFT){
      freq-=0.25;
    }
    if (keyCode==RIGHT){
      freq+=0.25;
    }
  }
}

void mousePressed(){
  if (mouseButton == LEFT){
    x=0;
    outGrid=false;
  }
  if (mouseButton == RIGHT){
    backgroundCurve=!backgroundCurve;
  }
}